On Media-Types, Content-Types, and related terminology

Status of This Memo

This Internet-Draft is submitted in full conformance with the provisions of BCP 78 and BCP 79.¶

Internet-Drafts are working documents of the Internet Engineering Task Force (IETF). Note that other groups may also distribute working documents as Internet-Drafts. The list of current Internet-Drafts is at https://datatracker.ietf.org/drafts/current/.¶

Internet-Drafts are draft documents valid for a maximum of six months and may be updated, replaced, or obsoleted by other documents at any time. It is inappropriate to use Internet-Drafts as reference material or to cite them other than as "work in progress."¶

This Internet-Draft will expire on 22 August 2021.¶

Copyright Notice

Copyright (c) 2021 IETF Trust and the persons identified as the document authors. All rights reserved.¶

This document is subject to BCP 78 and the IETF Trust's Legal Provisions Relating to IETF Documents (https://trustee.ietf.org/license-info) in effect on the date of publication of this document. Please review these documents carefully, as they describe your rights and restrictions with respect to this document. Code Components extracted from this document must include Simplified BSD License text as described in Section 4.e of the Trust Legal Provisions and are provided without warranty as described in the Simplified BSD License.¶

Table of Contents

1. Introduction

The key words "MUST", "MUST NOT", "REQUIRED", "SHALL", "SHALL NOT", "SHOULD", "SHOULD NOT", "RECOMMENDED", "NOT RECOMMENDED", "MAY", and "OPTIONAL" in this document are to be interpreted as described in BCP 14 [RFC2119] [RFC8174] when, and only when, they appear in all capitals, as shown here.¶

[RFC1590] introduced media types and their registration. That document took MIME types from [RFC1521] and gave them a new name. At that time, the term "media type" was often used just for the major type ("text", "audio"), and what we call a media-type now was the combination of a type and a subtype. This lives on in [RFC6838], which does not even have an ABNF [RFC5234] production for media type. [RFC6838]'s predecessor, [RFC4288], supplied the ABNF shown in (Figure 1).¶

type-name = reg-name
subtype-name = reg-name

reg-name = 1*127reg-name-chars
reg-name-chars = ALPHA / DIGIT / "!" /
                 "#" / "$" / "&" / "." /
                 "+" / "-" / "^" / "_"

¶

[RFC6838], obsoleting [RFC4288], restricts the first character of a reg-name to alphanumeric. It contains the otherwise semantically equivalent ABNF shown in Figure 2, however adding prose comments that further limit the use of "." and "+".¶

type-name = restricted-name
subtype-name = restricted-name

restricted-name = restricted-name-first *126restricted-name-chars
restricted-name-first  = ALPHA / DIGIT
restricted-name-chars  = ALPHA / DIGIT / "!" / "#" /
                         "$" / "&" / "-" / "^" / "_"
restricted-name-chars =/ "." ; Characters before first dot always
                             ; specify a facet name
restricted-name-chars =/ "+" ; Characters after last plus always
                             ; specify a structured syntax suffix

2. Media-Type

Today, the term "media type" is now generally used for a registered combination of a type-name and a subtype-name, as well as for the specification that defines the semantics of this combination. We further disambiguate by calling the former a media type name. An ABNF definition of Media-Type-Name:¶

Media-Type-Name = type-name "/" subtype-name

For the purposes of this memo, we define:¶

Media-Type-Name:

A combination of a type-name and a subtype-name registered in [IANA.media-types], conventionally identified by the two names separated by a slash.¶

(This leaves the term "Media Type" for the actual specification that is registered under the Media-Type-Name.)¶

3. Content-Type

Media types can have parameters [RFC6838], some of which are defined by the media type specification to be mandatory. In HTTP and many other protocols, media-type-names and parameters are then used together in a "Content-Type" header field. HTTP [RFC7231] uses the ABNF in Figure 4:¶

Content-Type = media-type
media-type = type "/" subtype *( OWS ";" OWS parameter )
type       = token
subtype    = token
token          = 1*tchar
tchar          = "!" / "#" / "$" / "%" / "&" / "'" / "*"
               / "+" / "-" / "." / "^" / "_" / "`" / "|" / "~"
               / DIGIT / ALPHA
OWS        = *( SP / HTAB )

¶

In the ABNF as established by [RFC2616], parts of which became [RFC7231], the rule name media-type is used for a Media-Type-Name with parameters attached. We don't follow this inclusive use of media-type; note that [RFC2616] was quite confused about this term by claiming (Section 3.7 of [RFC2616]):¶

• Media-type values are registered with the Internet Assigned Number Authority (IANA [19]).¶

This clearly reverts to the understanding of Media-Type-Name we use.¶

Instead of prolonging this confusion, we define as a separate term:¶

Content-Type:

A Media-Type-Name, optionally associated with parameters (separated from the media type name and from each other by a semicolon).¶

Removing the legacy HTAB characters now shunned in polite conversation, as well as some other cobwebs, we define the conventional textual representation of a Content-Type with the ABNF in Figure 5:¶

Content-Type   = Media-Type-Name *( *SP ";" *SP parameter )
parameter      = token "=" ( token / quoted-string )

token          = 1*tchar
tchar          = "!" / "#" / "$" / "%" / "&" / "'" / "*"
               / "+" / "-" / "." / "^" / "_" / "`" / "|" / "~"
               / DIGIT / ALPHA
quoted-string  = %x22 *qdtext %x22
qdtext         = SP / %x21 / %x23-5B / %x5D-7E

Note that there is a slight inconsistency between the "token" used here and the "reg-name"/"restricted-name" used above; since media type parameters probably will be defined within the guard rails set by [RFC7231], we need to use HTTP's more comprehensive definition here.¶

4. Content-Coding

Section 3.5 of [RFC2616] also introduced the term Content-Coding, a registered name for an encoding transformation that has been or can be applied to a representation:¶

content-coding   = token

Confusingly, in HTTP the Content-Coding is then given in a header field called "Content-Encoding"; we never use this term (except when we are in error). Instead we define:¶

Content-Coding:

a registered name for an encoding transformation that has been or can be applied to a representation.¶

Content-Codings are registered in the HTTP Content Coding Registry, a subregistry of [IANA.http-parameters]. We often use the "identity" Content-Coding, which is the identity transformation, and often fail to identify that Content-Coding by name, instead calling it "no Content-Coding".¶

5. Content-Format

CoAP, in Section 1 of [RFC7252], defines a Content-Format as the combination of a Content-Type and a Content-Coding, identified by a numeric identifier defined in the "CoAP Content-Formats" registry (a subregistry of [IANA.core-parameters]), but in more confusing words (it did not have the benefit of the present specifications).¶

Content-Format:

the combination of a Content-Type and a Content-Coding, identified by a numeric identifier defined by the "CoAP Content-Formats" subregistry of [IANA.core-parameters].¶

Note that there has not been a conventional string representation of just the combination of a Content-Type and a Content-Coding; Content-Formats so far always are identified by their registered Content-Format numbers. However, there are applications where that is useful [I-D.keranen-core-senml-data-ct], so we define:¶

Content-Format = "0" / (POS-DIGIT *DIGIT)
Content-Format-String   = Content-Type ["@" content-coding]

This allows the use of Content-Format-Strings such as "application/json@deflate" in place of the less self-describing content-format "11050", or other combinations that do not have a content-format number defined yet.¶

Content-Format-Strings MUST NOT explicitly use the content-coding value of "identity" (i.e., if an identity content-coding is desired, the entire optional part including the "@" sign is left out).¶

Note that a quoted string inside a content-type parameter might contain an "@" sign, so the parsing of Content-Format-Strings cannot be done in a too simplistic way.¶

6. Remaining ABNF

This specification uses the ABNF given in Figure 8, as originally defined in [RFC5234] and [RFC8866]:¶

DIGIT     =  %x30-39           ; 0 – 9
POS-DIGIT =  %x31-39           ; 1 – 9
ALPHA     =  %x41-5A / %x61-7A ; A – Z / a – z
SP        =  %x20

7. Abbreviations

Media type names are sometimes abbreviated as "mt", and Content-Types as "ct". We propose not to use those abbreviations: Where the long form of the values can be used, the long form "Content-Type" can also be used to name them.¶

For historical reasons, both [RFC6690] and [RFC7252] use the abbreviation "ct" for Content-Format (think first and last character).¶

For Content-Coding, the abbreviation "cc" can be used.¶

8. Discussion

The ABNF given here is provisional and may need some more cleanup, such as unifying the various forms of reg-name, token, etc.¶

(ABNF just shown for illustration is centered, in a blockquote, and tagged with <artwork type="abnf;old"...> in the XML, while the normative ABNF of this memo is left-aligned and tagged with <sourcecode type="abnf"...>.)¶

The XPath expression //sourcecode[@type='abnf']/text() can be used on the XML form of this specification to extract the ABNF defined here.¶

We need to discuss case-insensitivity at some point, which is usually rather insensitive.¶

9. Suggested usage

10. IANA Considerations

While this memo talks a lot about IANA registries, it does not require any action from IANA.¶

11. Security Considerations

Confusion about terminology may, in the worst case, cause security problems, as can loosely defined syntax elements of a specification. No other security considerations are known to be raised by the present specification.¶

Acknowledgements

Matthias Kovatsch forced the authors to make up their minds about this. Ari Keränen forced them to write it up, then, and created a convincing use case of Content-Format-Strings. John Mattsson alerted us to a mistake. Alexey Melnikov suggested reviving this draft after a year of dormancy.¶

Authors' Addresses